Fernsteuerung

Aus VBA-wiki
Zur Navigation springen Zur Suche springen

Zugriff auf PowerPoint

Bei PowerPoint reagiert 'CreateObject' wie folgt:

  • Wenn PowerPoint noch nicht läuft, wird es im Hintergrund gestartet.
  • Wenn PowerPoint schon läuft, wird dieses über 'CreateObject' zurückgegeben.
  • Wenn das Objekt freigegeben wird (spätestens am Ende der Prozedur), wird der Hintergrundprozess ebenfalls beendet.

Alternativ kann die Verbindung mit 'GetObject' hergestellt werden (siehe Beispiel für Word).

Public Sub InsertFormInPPT()
    Dim shp As PowerPoint.Shape
    Dim sld As PowerPoint.Slide
    Dim pptApp As PowerPoint.Application
    
    ' Voraussetzung: PowerPoint ist als Verweis eingebunden
    
    ' Anwendungsvariable mit PowerPoint verknüpfen
    ' Wenn PowerPoint nicht schon läuft, wird ein Hintergrundprozess gestartet
    Set pptApp = CreateObject("PowerPoint.Application")
    ' Wenn PowerPoint vorher schon vom Anwender gestartet wurde,
    ' ist die Anwendung sichtbar (auch wenn sie minimiert wurde)
    ' Wenn PowerPoint jetzt erst als Hintergrundprozess gestartet wurde, ist die Anwendung NICHT sichtbar
    If pptApp.Visible = False Then Exit Sub
    ' Mit der Referenz auf PowerPoint in der Variablen 'pptApp'
    ' kann nun direkt auf PowerPoint zugegriffen werden.
    If pptApp.Presentations.Count < 1 Then Exit Sub
    If pptApp.ActivePresentation.Slides.Count < 1 Then Exit Sub
    If pptApp.ActiveWindow.Selection.Type = ppSelectionNone Then Exit Sub
    Set sld = pptApp.ActiveWindow.Selection.SlideRange.Item(1)
    Set shp = sld.Shapes.AddShape(msoShapeRectangle, 10, 10, 230, 120)
    shp.Fill.ForeColor.RGB = vbMagenta
    shp.TextFrame.TextRange.Text = Excel.Application.Name
End Sub

Word

Bei Word reagiert 'CreateObject' wie folgt:

  • Wenn Word noch nicht läuft, wird ein neuer Hintergrundprozess gestartet.
  • Wenn Word schon läuft, wird trotzdem ein neuer Hintergrundprozess gestartet!
  • Wenn das Objekt freigegeben wird, bleibt der Hintergrundprozess erhalten!

Bei 'GetObject' gilt folgendes:

  • Wenn die Anwendung schon läuft, wird dessen Instanz zurückgegeben.
  • Wenn die Anwendung noch nicht läuft, wird ein Fehler erzeugt.
Public Sub TransferTextToWord()
    Dim wordApp As Word.Application
    Dim doc As Word.Document
    Dim rngWord As Word.Range
    
    ' Voraussetzung: Word ist als Verweis eingebunden
    
    On Error GoTo 0                 ' Setzt Fehlerspeicher auf 0 zurück
    On Error Resume Next            ' Falls ein Fehler auftritt, bitte weiter machen
    ' Achtung bei GetObject: Anwendung ist zweiter Parameter, erster bleibt leer!
    Set wordApp = GetObject(, "Word.Application")
    If Err.Number <> 0 Then         ' Wenn Fehlernummer ungleich 0, dann ...
        MsgBox "Bitte Word starten und gewünschtes Dokument öffnen!"
        On Error GoTo 0             ' Schaltet 'On Error Resume Next' aus
        Exit Sub
    End If
    On Error GoTo 0                 ' Schaltet 'On Error Resume Next' aus
'    Debug.Print 3 / 0               ' Erzeugt keinen Fehler, wenn 'On Error GoTo 0' fehlt!
    If wordApp.Documents.Count = 0 Then
        MsgBox "Bitte das gewünschte Dokument öffnen!"
        Exit Sub
    End If
    Set doc = wordApp.ActiveDocument
    Set rngWord = doc.Words.Item(3)
    rngWord.Text = Cells(1, 1).Text & " "
End Sub